{
	# Tour of the TTA core worlds.
	#
	# $Revision: 1.4 $ - $Date: 2007/08/06 15:25:14 $
	# by Jimmy "Gregor" McKinney
	#
	# TTA concept and material originally published 
	# as Spacecraft 2000 to 2100 AD
	# Copyright ©1990 Stewart Cowley
	# and licensed to Morrigan Press Inc.
	# Used with permission

	# Basic setup
	timerate { rate 0 }
	labels { clear "planets|moons|markers|minorplanets|stars|constellations|locations" }
	renderflags { set "stars|planets"         clear "constellations|orbits|markers" }
	set { name "StarStyle" value "scaleddiscs" }
	set { name "FOV" value 26.0 }

	time { utc "2173-05-17T03:29:24.0000" }

	print {text "TTA Data File AST-LGT-14634F\n2173:05:17 TST Reference" row -4  duration 3}
	wait {duration 3}
	preloadtex { object "Sol/Earth" }
	preloadtex { object "Sol/Earth/Moon" }
	print {text "Access Granted\nBeginning Local Systems Tour\nPlease stand by ..."  row -4  column 1  duration 4}
	wait {duration 4.0}


	select {object "Sol/Earth"}
	gotolonglat { time 7 distance 6 up [0 1 0] long 0 lat 0 }
	wait   {duration 3.0}
	print {text "Travelling to Sol System..." row -3}
	wait {duration 4.0}
	print {text "This is the homeworld of the Terran race, aka Humans.\n\nLocal name: Earth (Sol III)\nAlphan Standard: Dlaash boush tlaam krees Ala\nProximan: ChaaiBniilsajeet nillee*" row -6}
	orbit { axis [ 0 1 0 ] rate 30 duration 12 }

	wait {duration 2.0 }

	# Alpha Centauri Section Start
	preloadtex { object "Rigel Kentaurus A/Alpha I" }
	preloadtex { object "Rigel Kentaurus A/Alpha I/Tlaam ^een" }
	preloadtex { object "Rigel Kentaurus A/Alpha III" }

	select {object "Rigel Kentaurus A"}
	# center { time 3 }
	# wait { duration 3 }
	goto   {time 5 distance 15000}
	print {text "Alpha Centauri is a binary system, consisting of the yellow star Alpha A and the orange star Alpha B." row -3}
	wait {duration 8 }

	goto  {time 5 distance 30}
	# gotolonglat { time 5 distance 30 up [0 1 0] long 0 lat 0 }
	print {text "We are now travelling to the larger, yellow star.\n\nTerran name: Alpha Centauri A\nAlphan Standard:  Dlaash kreesh\nProximan: Diiraaitola" row -6}
	wait {duration 7 }

	select {object "Rigel Kentaurus A/Alpha I"}
	goto   {time 5.0  distance 6.0 upframe "equatorial"}
	wait   {duration 1.0}
	print {text "This is the homeworld of the Alphan people.\n\nTerran name: Alpha I\nAlphan Standard: (Dlaash krees) Tlaam krees Osha\nProximan: ChaaiBniilsajeet peema (1 Diiraaitola Ajeetaam)" row -6}
	wait   {duration 4.5}
	orbit { axis [ 0 1 0 ] rate 30 duration 12 }

	wait { duration 2 }

	# Go to Alpha's moon
	select {object "Rigel Kentaurus A/Alpha I/Alpha I a"}
	goto   {time 3.0  distance 6.0 upframe "equatorial"}
	wait   {duration 1.0}
	print {text "Alpha I has one moon, Tlaam ^een.  It appears much larger than Luna does from Earth." row -3}	
	wait   {duration 2.0}
	orbit { axis [ 0 1 0 ] rate 30 duration 12 }

	#wait { duration 2 }

	# Go to Alpha III
	labels { set "moons" }
	select {object "Rigel Kentaurus A/Alpha III"}
	# goto   {time 5.0  distance 10.0 upframe "equatorial"}
	gotolonglat { time 5 distance 10 up [0 1 0] long 0 lat 5 }
	wait   {duration 1.0}
	print {text "This gas giant is an important resource for the Alphans.\n\nTerran name: Alpha III\nAlphan Standard:  (Dlaash krees) Tlaam krees Ala\nProximan: 3 Diiraaitola Ajeetaam" row -6}	
	wait   {duration 4.0}
	orbit { axis [ 0 1 0 ] rate 30 duration 12 }

	wait { duration 2 }

	# Show overview of Alpha A system
	select {object "Rigel Kentaurus A"}
	goto   {time 4.0  distance 1500 upframe "equatorial"}
	wait {duration 1}
	print {text "Let's get an overview of Alpha A's System..." row -3 duration 3}
	wait   {duration 3.5}
	labels { clear "moons" }
	labels { set "planets" }
	renderflags { set "orbits"}
	orbit { axis [ 1 0 0 ] rate 45 duration 2 }

	changedistance { duration 5 rate 0.3 }
	wait { duration 2 }
	print {text "Alpha A has three planets.  The gap between the second and third is home to many asteroids." row -3 duration 3}
	wait   {duration 4.0}

	changedistance { duration 6 rate 0.25 }

	print {text "Now we see the planetary system of the companion, Alpha B.\nIt has three planets as well." row -3 duration 3}
	wait   {duration 6.0}

	# Show overview of Alpha B system
	select {object "Rigel Kentaurus B"}
	center {}
	follow {}
	changedistance { duration 6 rate -0.5 }
	print {text "A closer look.\n\nTerran name: Alpha Centauri B\nAlphan Standard:  Dlaash ^een\nProximan: Diiraaihucha" row -6}
	wait { duration 8 }

	# Go to Alpha B-2
	labels { set "moons" clear "planets" }
	renderflags { clear "orbits"}
	select {object "Rigel Kentaurus B/Alpha B-II"}
	gotolonglat { time 5 distance 6 up [0 1 0] long 0 lat 0 }
	wait   {duration 1.0}
	print {text "This planet is an Alphan colony world with two moons.\n\nTerran name: Alpha B-II\nAlphan Standard:  (Dlaash ^een) Tlaam krees Oto\nProximan: 2 Diiraaihucha ajeetaam" row -6}	
	wait   {duration 4.5}
	orbit { axis [ 0 1 0 ] rate -30 duration 6 }

	print {text "The blue-green light in the oceans at night is caused by bioluminescent\nlifeforms, which are plentiful enough to be seen even from space." row -4}
	orbit { axis [ 0 1 0 ] rate -30 duration 6 }

	# Proxima Centauri section
	preloadtex { object "Proxima/Proxima II" }
	preloadtex { object "Proxima/Proxima IV" }
	wait   {duration 2 }

	# Go to Proxima
	select {object "Proxima"}
	center { time 3 }
	wait { duration 3 }
	#goto   {time 10.0  distance 30 upframe "equatorial"}
	gotolonglat { time 2 distance 30 up [0 1 0] long 0 lat 0 }
	wait {duration 1}
	print {text "This nearby red dwarf star was once considered Alpha Centauri C.\n\nTerran name: Proxima Centauri\nAlphan Standard:  Dlaash slen\nProximan: Moog" row -6}
	wait { duration 10 }

	select {object "Proxima/Proxima II"}
	gotolonglat { time 5 distance 6 up [0 1 0] long 0 lat 0 }
	#goto   {time 5.0  distance 6.0 upframe "equatorial"}
	wait { duration 1.5 }
	print {text "This is the homeworld of the Proximan people.\n\nTerran name: Proxima II\nAlphan Standard: (Dlaash slen) Tlaam krees Oto\nProximan: ChaaiBqelsajeet (2 Moog ajeetaam)" row -6}
	wait   {duration 4.0}
	orbit { axis [ 0 1 0 ] rate 30 duration 5.5 }
	print {text "Proxima II is tidally locked, so this half of the planet is in perpetual night and cold,\nwhile the day side is constantly lit and warm." row -4}
	orbit { axis [ 0 1 0 ] rate 30 duration 6.5 }


	wait { duration 1 }
	#gotolonglat { time 2 distance 6 up [0 1 0] long 0 lat 0 }
	renderflags { set "markers" }
	print {text "We are now at a point directly between the planet and the star.\nThe point marked is always the hottest, creating a large central desert." row -4}	
	wait { duration 1 }
	renderflags { clear "markers" }
	wait { duration 1 }
	renderflags { set "markers" }
	wait { duration 1 }
	renderflags { clear "markers" }
	wait { duration 1 }
	renderflags { set "markers" }
	wait { duration 1 }
	renderflags { clear "markers" }
	wait { duration 1 }
	renderflags { set "markers" }
	wait { duration 1 }
	renderflags { clear "markers" }
	wait { duration 3 }

	# Show Proxima II's orbit

	renderflags { clear "markers"}
	print {text "Let's watch Proxima II's behavior." row -3}
	orbit { axis [ 1 0 0 ] rate 30 duration 3 }
	wait { duration 0.5 }
	changedistance { duration 2.5 rate 0.3 }
	follow { }
	wait { duration 1 }
	print {text "We will speed up time by a factor of 10000.\nProxima II takes less than four earth days to orbit its star." row -4}
	wait { duration 5 }
	timerate { rate 10000 }

	wait { duration 15.4 }
	print {text "Note how the planet keeps the same face toward the star." row -4}
	synchronous { }
	wait { duration 5 }
	print {text "Now we'll see it from another angle." row -4}
	orbit { axis [ -1 0 0 ] rate 30 duration 3 }
	wait { duration 10 }

	# Proxima IV
	timerate { rate 0 }
	time { utc "2173-05-17T03:29:24.0000" }
	select {object "Proxima/Proxima IV"}
	gotolonglat { time 5 distance 6 up [0 1 0] long 0 lat 0 }
	wait { duration 1.0 }
	print {text "This planet is extremely odd.  It should be frozen solid, but it isn't.\nIt is also queerly similar to Alpha B-II." row -4}
	wait   {duration 4.5 }
	orbit { axis [ 0 1 0 ] rate 30 duration 5 }
	print {text "Terran name: Proxima IV\nAlphan Standard: (Dlaash slen) Tlaam krees AasO\nProximan: Skeeklatjan (4 moog ajeetaam)" row -5}
	orbit { axis [ 0 1 0 ] rate 30 duration 7 }

	# Show overview of Proxima System
	select {object "Proxima"}
	goto   {time 5.0  distance 1500 upframe "equatorial"}
	# gotolonglat { time 5 distance 1600 up [0 1 0] long 0 lat 0 }
	wait {duration 1}
	print {text "Finally, let's look at the planetary system" row -3}
	wait { duration 4.5 }
	labels { set "planets" }
	renderflags { set "orbits" }
	orbit { axis [ 1 0 0 ] rate 30 duration 3 }
	changedistance { duration 5 rate 0.56 }

	wait { duration 2 }
	print {text "This concludes this tour of the local systems.\nFor additional tours, please consult the database guide." row -4 duration 4 }
}